it-swarm-eu.dev

Come ottenere il nome del file solo senza percorso nella riga di comando di Windows?

for /r %f in (*) do echo %f

Fornisce il nome file di output insieme all'intero percorso

\path\to\dir\<filename>

Come faccio a ottenere il <filename> senza il percorso incluso? Ho bisogno di usare quella stringa 'filename'.

Inoltre, è possibile fare quanto segue, una volta acquisito il nome del file?

for /r %%f in (*) do (
echo "blah blah blah 'filename'" >> blahblah_filename.txt
)
28
Jay

Utilizza %~nxf per <filename>.<extension>.

E sì, puoi fare:

for /r %%f in (*) do (
echo "blah blah blah '%%~nxf'" >> blahblah_%%~nxf.txt
)

Vedi for /?:

In addition, substitution of FOR variable references has been enhanced.
You can now use the following optional syntax:

    %~I         - expands %I removing any surrounding quotes (")
    %~fI        - expands %I to a fully qualified path name
    %~dI        - expands %I to a drive letter only
    %~pI        - expands %I to a path only
    %~nI        - expands %I to a file name only
    %~xI        - expands %I to a file extension only
    %~sI        - expanded path contains short names only
    %~aI        - expands %I to file attributes of file
    %~tI        - expands %I to date/time of file
    %~zI        - expands %I to size of file
    %~$PATH:I   - searches the directories listed in the PATH
                   environment variable and expands %I to the
                   fully qualified name of the first one found.
                   If the environment variable name is not
                   defined or the file is not found by the
                   search, then this modifier expands to the
                   empty string

The modifiers can be combined to get compound results:

    %~dpI       - expands %I to a drive letter and path only
    %~nxI       - expands %I to a file name and extension only
    %~fsI       - expands %I to a full path name with short names only
    %~dp$PATH:I - searches the directories listed in the PATH
                   environment variable for %I and expands to the
                   drive letter and path of the first one found.
    %~ftzaI     - expands %I to a DIR like output line

In the above examples %I and PATH can be replaced by other valid
values.  The %~ syntax is terminated by a valid FOR variable name.
Picking upper case variable names like %I makes it more readable and
avoids confusion with the modifiers, which are not case sensitive.
46
Bob

Non sono ancora in grado di commentare, ma credo che si debba tenere presente quanto segue per evitare confusione.

Mentre f può essere usato come un nome di variabile FOR, è meglio usare un'altra lettera per evitare di confonderla con il formato lettera f (che, come indicato nella risposta di Bob, restituisce il nome completo del percorso), o almeno usa un F maiuscolo.

0
HYBRID BEING